Conversion of a VW POLO with an AC industrial motor

/* EPAS CONTROL UNIT - Open loop, manually adjustable feedback
 * Designed by C. Silva - Acessory & user interface PCB's - The Electric VW project (2012-2015)
 ** December 2015 **
 * 
 * ---------------------------------------------------------------------------------------------------------------------------------------
 * 
 * ADC inputs:
 * Analog potentiometer. 0 to VCC, 128 levels.
 * 
 * Outputs:
 * Output 1: Engine Running signal, SQUARE WAVE, 35Hz
 * Output 2: Power steering assist level. User adjustable from 55 to 218Hz
 * Output 3: Blinking Indicator
 *
 ****************************************************************************************************************************************/


  //Define CPU Clock, to correctly set up the delay function
  #define F_CPU 1200000    // 9.6MHz with CLKDIV8 Fuse Enabled = 1.2MHz
  
  //Atmel delay function
  #include <util/delay.h>
  
  byte adc = 0;       // Variable to store ADC result
  // byte output = 0;    // Used to delay EPAS startup
  uint16_t i = 0;     // Variable to store count value for non blocking delay

// ---------------------------------------------------------------------------------------------------------------

void setup() {

  DDRB |= _BV(0); //Make (PB0) an output        // Engine running indicator output
  DDRB |= _BV(1); //Make (PB1) an output        // EPAS control Output
  DDRB &= ~_BV(2); //Make (PB2) an input        // ADC for user selectable assist level       
  DDRB |= _BV(4); //Make (PB4) an output        // Blinking Indicator
  
  SREG = 128;                                   // Global Interrupt Enable
  
  TCCR0A = 0;
  TIMSK0 = 0;                             

  //ADMUX |= (1 << REFS0);                      // Set ADC reference to AVCC
  ADMUX |= (1 << ADLAR);                        // Left Adjust the result 
  ADCSRA |= (1 << ADEN);                        // Enable ADC
  ADCSRA |= (1 << ADIE);                        // Enable ADC Interrupt
  ADCSRA |= (1 << ADSC);                        // Start A2D Conversions  
    

  // PWM Configuration
  // Pag 78 Datasheet, Table 11.3 - Fast PWM (32KHz)
  // OCOA/PB0 - Non Inverting Mode, Clear on Compare match, Set on Bottom
  // OC0B/PB1 - Disconnected, Normal I/O operation (This is toggled by software inside the COMPB Interrupt)
  
  /* The overflow flag is used by the damm arduino compiler, so without changing registers
  and going crazy we can use hardware PWM as alternative to create a fixed frequency sq wave*/  
  OCR0A = 128;                 // Set Duty cycle = 50%
                               // This is a 73.42 Hz signal to enable the EPAS (AKA Engine Running)
  
  TCCR0B |= 1<<CS01 | 1<<CS00 | 1<<FOC0A;  // Prescaller = 64, therefore clock = 73.24Hz/2 = 36.62Hz
  
  _delay_ms(4000);  // Wait 4 seconds for the DC-DC Converter to boot up and voltages stabilize.
  
  // Enable the EPAS, by turning the PWM square wave signal output on.
  TCCR0A |= 1<<COM0A0 | 0<<COM0B0 | 0<<WGM00;  // SET WGM00 FOR OPERATING MODE. 0 = NORMAL, 3 = FAST PWM, ETC    
  // output = 1;                  // Wait for voltages to stabilize before enabling the EPAS  
  TIMSK0 |= (1 << OCIE0B);                      // Enable COMPB Interrupt
}

// ---------------------------------------------------------------------------------------------------------------

// the loop function runs over and over again forever
void loop() 
{
}

// ---------------------------------------------------------------------------------------------------------------

ISR(ADC_vect) 
{  
  // Select ADC3 (PB3) - Pag 135 Datasheet
  // Let Justify the result (8bit reading)
  ADMUX = (1 << MUX0)|(1 << ADLAR);

  /* HOW THE FREQUENCIES ARE CALCULATED:
         CLKDIV8 FUSE = ENABLED
         DEFAULT PRESCALLER = 64 <-> 9600000/8/64/256 = 73.24Hz
         OUTPUT toggled on each cycle, therefore 73/2 = 36.62Hz
         The 8 bit ADC reading is shifted once, giving rise to a 0 to 127 read.
         
         Chose the minimun frequency value = 170
         9600000/8/64/170/2 = 55.14Hz
         
         Choose the maximun frequency value = 170-127 = 43
         9600000/8/64/43/2 = 218Hz
   */
  adc = (170-(ADCH>>1));     
  ADCSRA |= (1 << ADSC);     // Start A2D Conversions 
}

                             
ISR(TIM0_COMPB_vect)
{
  // Togle Pin 
  PINB |= _BV(PORTB1);       // This is the speed signal for the EPAS, to set assit power level
  OCR0B = (OCR0B+adc);
  
  //Set up a non blocking delay
  i++;
  if (i>255)
    {
      PINB |= _BV(PORTB4);   // Blink a LED to indicate operation   
      i=0;  
    }
}